AWS User Notifications の Terraform モジュールを作ってみた

resource "aws_notifications_notification_configuration" "this" {
  name                 = var.name
  description          = var.description
  aggregation_duration = var.aggregation_duration
  tags                 = var.tags
}

resource "aws_notificationscontacts_email_contact" "this" {
  for_each = var.email_contacts

  name          = each.value.name
  email_address = each.value.email_address
  tags          = var.tags
}

resource "aws_notifications_event_rule" "this" {
  for_each = var.event_rules

  source                         = each.value.source
  event_type                     = each.value.event_type
  event_pattern                  = each.value.event_pattern == null ? null : jsonencode(each.value.event_pattern)
  regions                        = var.regions
  notification_configuration_arn = aws_notifications_notification_configuration.this.arn
}

resource "aws_notifications_channel_association" "this" {
  for_each = aws_notificationscontacts_email_contact.this

  arn                            = each.value.arn
  notification_configuration_arn = aws_notifications_notification_configuration.this.arn
}

variable "name" {
  description = "Notification configuration name."
  type        = string

  validation {
    condition     = length(var.name) >= 1 && length(var.name) <= 64
    error_message = "name must be between 1 and 64 characters."
  }
}

variable "description" {
  description = "Notification configuration description."
  type        = string

  validation {
    condition     = length(var.description) <= 256
    error_message = "description must be 256 characters or fewer."
  }
}

variable "aggregation_duration" {
  description = "Aggregation preference. Valid values are NONE, SHORT, and LONG."
  type        = string
  default     = "NONE"

  validation {
    condition     = contains(["NONE", "SHORT", "LONG"], var.aggregation_duration)
    error_message = "aggregation_duration must be one of NONE, SHORT, or LONG."
  }
}

variable "regions" {
  description = "Regions where source events are monitored. This is not the notification hub region setting."
  type        = set(string)

  validation {
    condition     = length(var.regions) > 0
    error_message = "regions must contain at least one monitored event region."
  }
}

variable "email_contacts" {
  description = "Email contacts to create and associate with the notification configuration."
  type = map(object({
    name          = string
    email_address = string
  }))

  validation {
    condition     = length(var.email_contacts) > 0
    error_message = "email_contacts must contain at least one email contact."
  }
}

variable "event_rules" {
  description = "Event rules associated with the notification configuration."
  type = map(object({
    source        = string
    event_type    = string
    event_pattern = optional(any, null)
  }))

  validation {
    condition     = length(var.event_rules) > 0
    error_message = "event_rules must contain at least one event rule."
  }

  validation {
    condition = alltrue([
      for rule in values(var.event_rules) :
      startswith(rule.source, "aws.") && length(rule.event_type) > 0
    ])
    error_message = "Each event rule must use an AWS event source such as aws.health and a non-empty event_type."
  }
}

variable "tags" {
  description = "Tags applied to supported resources."
  type        = map(string)
  default     = {}
}

output "notification_configuration_arn" {
  description = "ARN of the notification configuration."
  value       = aws_notifications_notification_configuration.this.arn
}

output "email_contact_arns" {
  description = "ARNs of the email contacts created by this module."
  value = {
    for key, contact in aws_notificationscontacts_email_contact.this :
    key => contact.arn
  }
}

output "event_rule_arns" {
  description = "ARNs of the event rules created by this module."
  value = {
    for key, rule in aws_notifications_event_rule.this :
    key => rule.arn
  }
}

terraform {
  required_version = ">= 1.3.0"

  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = ">= 6.26.0"
    }
  }
}

provider "aws" {
  region = "ap-northeast-1"
}

module "notice" {
  source = "../../"

  name                 = "smpl-user-notif-cloudwatch-alarm"
  description          = "CloudWatch alarm sample notification"
  aggregation_duration = "NONE"
  regions              = ["ap-northeast-1"]

  email_contacts = {
    myself = {
      name          = "myself"
      email_address = "${Eメールアドレス}"
    }
  }

  event_rules = {
    cloudwatch_alarm = {
      source     = "aws.cloudwatch"
      event_type = "CloudWatch Alarm State Change"
      event_pattern = {
        detail = {
          state = {
            value = ["ALARM"]
          }
        }
      }
    }
  }
}