Amazon Inspectorを使ったECRスキャンでスキャン結果にイメージを使用しているECSタスク・EKS Pod情報がマッピングされるようになりました

# Lambda関数用のIAMロール
resource "aws_iam_role" "lambda_role" {
  name = "ecr_scan_lambda_role"

  assume_role_policy = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Action = "sts:AssumeRole"
        Effect = "Allow"
        Principal = {
          Service = "lambda.amazonaws.com"
        }
      }
    ]
  })
}

# Lambda基本実行権限とCloudWatch Logs権限をアタッチ
resource "aws_iam_role_policy_attachment" "lambda_basic" {
  role       = aws_iam_role.lambda_role.name
  policy_arn = "arn:aws:iam::aws:policy/service-role/AWSLambdaBasicExecutionRole"
}

# Lambda関数用のコードをzipファイルとして準備
data "archive_file" "lambda_zip" {
  type        = "zip"
  output_path = "${path.module}/lambda_function.zip"
  
  source {
    content  = <<EOF
import json
import logging

logger = logging.getLogger()
logger.setLevel(logging.INFO)

def lambda_handler(event, context):
    """ECRスキャンイベントを受け取り、内容をログに出力する関数"""
    
    # イベント全体をログに出力
    logger.info("ECRスキャンイベント:")
    logger.info(json.dumps(event, indent=2, default=str))
    
    return {
        'statusCode': 200,
        'body': 'イベント処理完了'
    }
EOF
    filename = "lambda_function.py"
  }
}

# Lambda関数の作成
resource "aws_lambda_function" "ecr_scan_lambda" {
  function_name    = "ecr-scan-event-processor"
  role             = aws_iam_role.lambda_role.arn
  handler          = "lambda_function.lambda_handler"
  filename         = data.archive_file.lambda_zip.output_path
  source_code_hash = data.archive_file.lambda_zip.output_base64sha256
  runtime          = "python3.9"
  timeout          = 10
  
  tags = {
    Name = "ECRScanEventProcessor"
  }
}

# EventBridgeルールの作成
resource "aws_cloudwatch_event_rule" "ecr_scan_rule" {
  name        = "ecr-scan-events"
  description = "キャプチャするECRスキャンイベント"
  
  event_pattern = jsonencode({
    source      = ["aws.inspector2"]
    detail-type = ["Inspector2 Scan"]
  })
}

# EventBridgeルールのターゲットとしてLambda関数を設定
resource "aws_cloudwatch_event_target" "lambda_target" {
  rule      = aws_cloudwatch_event_rule.ecr_scan_rule.name
  target_id = "SendToLambda"
  arn       = aws_lambda_function.ecr_scan_lambda.arn
}

# EventBridgeがLambda関数を呼び出す権限を付与
resource "aws_lambda_permission" "allow_eventbridge" {
  statement_id  = "AllowExecutionFromEventBridge"
  action        = "lambda:InvokeFunction"
  function_name = aws_lambda_function.ecr_scan_lambda.function_name
  principal     = "events.amazonaws.com"
  source_arn    = aws_cloudwatch_event_rule.ecr_scan_rule.arn
}

{
    "version": "0",
    "id": "b2a9391d-0e8e-1f3b-db45-baba7da0ee63",
    "detail-type": "Inspector2 Scan",
    "source": "aws.inspector2",
    "account": "XXXXXXXXXXXX",
    "time": "2025-05-20T00:04:37Z",
    "region": "us-east-1",
    "resources": [
        "arn:aws:ecr:us-east-1:XXXXXXXXXXXX:repository/test-ecspresso-test"
    ],
    "detail": {
        "scan-status": "INITIAL_SCAN_COMPLETE",
        "repository-name": "arn:aws:ecr:us-east-1:XXXXXXXXXXXX:repository/test-ecspresso-test",
        "finding-severity-counts": {
            "CRITICAL": 0,
            "HIGH": 2,
            "MEDIUM": 0,
            "TOTAL": 2
        },
        "image-digest": "sha256:4c24505bb7aed4b33db21a9a9ac91a947e71bb6cbcfa3f8b40e5c0f6fbb734d7",
        "image-tags": [
            "v4"
        ],
        "version": "1.0"
    }
}