既存 TiDB Cloud Starter (旧: Serverless) クラスタを Terraform 管理へ import する

brew tap hashicorp/tap
brew install hashicorp/tap/terraform
terraform -version

export TIDBCLOUD_PUBLIC_KEY="xxxxxxxx"
export TIDBCLOUD_PRIVATE_KEY="xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx"

terraform {
  required_version = ">= 1.0.0"
  required_providers {
    tidbcloud = {
      source  = "tidbcloud/tidbcloud"
      version = "~> 0.4.0"
    }
  }
}

provider "tidbcloud" {
  # 環境変数 TIDBCLOUD_PUBLIC_KEY と TIDBCLOUD_PRIVATE_KEY を自動検出
  sync = true  # クラスタ関連の操作を同期で待機
}

variable "tidbcloud_project_id" {
  description = "TiDB Cloud project id"
  type        = string
}

variable "cluster_region" {
  description = "Starter のリージョン名 正規形を指定 例: regions/aws-eu-central-1 や regions/aws-ap-northeast-1"
  type        = string
}

variable "display_name" {
  description = "クラスタの表示名"
  type        = string
  default     = "my-starter-db"
}

resource "tidbcloud_serverless_cluster" "starter" {
  project_id   = var.tidbcloud_project_id
  display_name = var.display_name

  region = {
    provider = "AWS"
    name     = var.cluster_region
  }

  lifecycle {
    prevent_destroy = true
    ignore_changes  = [display_name]
  }
}

export TF_VAR_tidbcloud_project_id="xxxxxxxxxxxxxxxxxxx"
export TF_VAR_cluster_region="regions/aws-eu-central-1"  # 正規形を指定

terraform init -reconfigure # -reconfigure はバックエンドやプロバイダ設定を強制的に再読み込みします。既存の作業ディレクトリでも安全に繰り返し実行できます。
terraform validate
terraform plan

# import 専用の環境変数として cluster_id を用意
export TIDB_CLUSTER_ID="xxxxxxxxxxxxxxxxxxxx"

# まだ state に無ければ取り込む (単一リソース管理)
terraform state list | grep -q '^tidbcloud_serverless_cluster\.starter$' || \
  terraform import tidbcloud_serverless_cluster.starter "$TIDB_CLUSTER_ID"

# 例: modules/tidb 内に定義している場合
terraform state list | grep -q '^module\.tidb\.tidbcloud_serverless_cluster\.starter$' || \
  terraform import module.tidb.tidbcloud_serverless_cluster.starter "$TIDB_CLUSTER_ID"

terraform plan -refresh-only

tidbcloud_serverless_cluster.starter: Refreshing state...

No changes. Your infrastructure still matches the configuration.

Terraform has checked that the real remote objects still match the result of your most recent changes, and found no
differences.

───────────────────────────────────────────────────────────────────────────────────────────────────────────────────────

Note: You didn't use the -out option to save this plan, so Terraform can't guarantee to take exactly these actions if
you run "terraform apply" now.