WordPressのブログを静的化してCloudFront+S3に移行してみた

# 静的サイト用S3バケット
resource "aws_s3_bucket" "static_site" {
  bucket = "${var.project_name}-${var.environment}-static-site"
  tags = {
    Name        = "${var.project_name}-${var.environment}-static-site"
    Environment = var.environment
    Project     = var.project_name
  }
}

# CloudFrontログ用S3バケット
resource "aws_s3_bucket" "cloudfront_logs" {
  bucket = "${var.project_name}-${var.environment}-cloudfront-logs"
  tags = {
    Name        = "${var.project_name}-${var.environment}-cloudfront-logs"
    Environment = var.environment
    Project     = var.project_name
  }
}

# CloudFrontログ用S3バケットのACL設定
resource "aws_s3_bucket_ownership_controls" "cloudfront_logs" {
  bucket = aws_s3_bucket.cloudfront_logs.id
  rule {
    object_ownership = "BucketOwnerPreferred"
  }
}

resource "aws_s3_bucket_acl" "cloudfront_logs" {
  depends_on = [aws_s3_bucket_ownership_controls.cloudfront_logs]
  bucket = aws_s3_bucket.cloudfront_logs.id
  acl    = "private"
}

# ログの自動削除設定（コスト削減のため）
resource "aws_s3_bucket_lifecycle_configuration" "cloudfront_logs" {
  bucket = aws_s3_bucket.cloudfront_logs.id
  rule {
    id     = "delete_old_logs"
    status = "Enabled"
    filter {
      # 空のfilterは全てのオブジェクトに適用
    }
    expiration {
      days = 90  # 90日後に自動削除
    }
  }
}

resource "aws_cloudfront_origin_access_control" "static_site" {
  name                              = "${var.project_name}-${var.environment}-oac"
  description                      = "OAC for ${var.project_name} static site"
  origin_access_control_origin_type = "s3"
  signing_behavior                  = "always"
  signing_protocol                  = "sigv4"
}

resource "aws_cloudfront_function" "uri_rewrite" {
  name    = "${var.project_name}-${var.environment}-uri-rewrite"
  runtime = "cloudfront-js-2.0"
  comment = "URI rewrite function for clean URLs"
  publish = true
  code    = file("${path.module}/functions/uri-rewrite.js")
}

resource "aws_cloudfront_distribution" "static_site" {
  origin {
    domain_name              = aws_s3_bucket.static_site.bucket_regional_domain_name
    origin_id                = "S3-${aws_s3_bucket.static_site.bucket}"
    origin_access_control_id = aws_cloudfront_origin_access_control.static_site.id
  }

  enabled             = true
  is_ipv6_enabled     = true
  comment             = "${var.project_name} static site distribution"
  default_root_object = "index.html"

  # ドメイン設定（後ほど設定予定）
  # aliases = [var.domain_name]

  # CloudFrontログ設定
  logging_config {
    include_cookies = false
    bucket         = aws_s3_bucket.cloudfront_logs.bucket_domain_name
    prefix         = "access-logs/"
  }

  default_cache_behavior {
    allowed_methods  = ["DELETE", "GET", "HEAD", "OPTIONS", "PATCH", "POST", "PUT"]
    cached_methods   = ["GET", "HEAD"]
    target_origin_id = "S3-${aws_s3_bucket.static_site.bucket}"

    forwarded_values {
      query_string = false
      cookies {
        forward = "none"
      }
    }

    viewer_protocol_policy = "redirect-to-https"
    min_ttl                = 0
    default_ttl            = 3600
    max_ttl                = 86400
    compress               = true

    function_association {
      event_type   = "viewer-request"
      function_arn = aws_cloudfront_function.uri_rewrite.arn
    }
  }

  # 404エラー時に用意された404ページを表示
  custom_error_response {
    error_code            = 404
    response_code         = 404
    response_page_path    = "/404/index.html"
    error_caching_min_ttl = 0
  }

  # 403エラー時も404ページを表示（S3のアクセス拒否時）
  custom_error_response {
    error_code            = 403
    response_code         = 404
    response_page_path    = "/404/index.html"
    error_caching_min_ttl = 0
  }

  price_class = "PriceClass_200"

  restrictions {
    geo_restriction {
      restriction_type = "none"
    }
  }

  viewer_certificate {
    # デフォルト証明書を使用（ACMは後ほど設定予定）
    cloudfront_default_certificate = true
    # ACMの証明書設定（後ほど有効化）
    # acm_certificate_arn      = var.acm_certificate_arn
    # ssl_support_method       = "sni-only"
    # minimum_protocol_version = "TLSv1.2_2021"
    # cloudfront_default_certificate = false
  }

  tags = {
    Name        = "${var.project_name}-${var.environment}-distribution"
    Environment = var.environment
    Project     = var.project_name
  }
}

resource "aws_s3_bucket_policy" "static_site" {
  bucket = aws_s3_bucket.static_site.id
  policy = templatefile("${path.module}/policy/s3-cloudfront-policy.json", {
    s3_bucket_arn             = aws_s3_bucket.static_site.arn
    cloudfront_distribution_arn = aws_cloudfront_distribution.static_site.arn
  })
}