カスタム権限でカスタムMCPツールの実行を特定ユーザーだけに制限してみた

    /**
     * このツールの実行を許可するカスタム権限の API 参照名。
     * 許可するプロファイル/権限セットに、この権限を割り当てて運用する。
     */
    @TestVisible
    private static final String REQUIRED_PERMISSION = 'Log_Opportunity_Meeting_Note';

    /**
     * 権限不足など、ツールを実行できない場合に送出する例外。
     */
    global class LogOpportunityMeetingNoteException extends Exception {}

        // 実行ユーザーがカスタム権限を保持していなければ中断する。
        // throw により MCP クライアントへエラーが返り、活動は一切作成されない。
        if (!FeatureManagement.checkPermission(REQUIRED_PERMISSION)) {
            throw new LogOpportunityMeetingNoteException(
                'この操作を実行する権限がありません。' +
                '管理者にカスタム権限「商談メモを活動として記録」の付与を依頼してください。'
            );
        }

/**
 * 商談メモ（議事録）を、指定した商談に紐づく完了済みの活動(ToDo / Task)として記録する Invocable Action。
 * カスタム MCP サーバーのツールとして公開して利用する。
 *
 * 【実行制限】カスタム権限「Log_Opportunity_Meeting_Note」を保持するユーザーのみ
 *  実行できる。許可したいプロファイルまたは権限セットにこのカスタム権限を割り当てること。
 */
global with sharing class LogOpportunityMeetingNote {

    /**
     * このツールの実行を許可するカスタム権限の API 参照名。
     * 許可するプロファイル/権限セットに、この権限を割り当てて運用する。
     */
    @TestVisible
    private static final String REQUIRED_PERMISSION = 'Log_Opportunity_Meeting_Note';

    /**
     * 権限不足など、ツールを実行できない場合に送出する例外。
     */
    global class LogOpportunityMeetingNoteException extends Exception {}

    global class Request {
        @InvocableVariable(label='商談ID' description='メモを紐付ける商談(Opportunity)のレコードID' required=true)
        global Id opportunityId;

        @InvocableVariable(label='メモ本文' description='活動として記録する議事録・商談メモの本文' required=true)
        global String notes;

        @InvocableVariable(label='件名' description='活動の件名。未指定の場合は「商談メモ」を使用')
        global String subject;

        @InvocableVariable(label='活動日' description='活動の日付。未指定の場合は本日')
        global Date activityDate;

        @InvocableVariable(label='関連連絡先ID' description='メモに紐付ける担当者(Contact)のレコードID（任意）')
        global Id contactId;
    }

    global class Result {
        @InvocableVariable(label='作成された活動ID' description='登録された活動(Task)のレコードID')
        global Id taskId;
    }

    @InvocableMethod(
        label='商談メモを活動として記録'
        description='議事録・商談メモを、指定した商談に紐づく完了済みの活動(ToDo)として記録します。'
    )
    global static List<Result> logMeetingNotes(List<Request> requests) {
        // 実行ユーザーがカスタム権限を保持していなければ中断する。
        // throw により MCP クライアントへエラーが返り、活動は一切作成されない。
        if (!FeatureManagement.checkPermission(REQUIRED_PERMISSION)) {
            throw new LogOpportunityMeetingNoteException(
                'この操作を実行する権限がありません。' +
                '管理者にカスタム権限「商談メモを活動として記録」の付与を依頼してください。'
            );
        }

        // 組織のロケール（"完了"/"Completed" 等）に依存しないよう、
        // クローズ扱いの状況(Status)を動的に取得する。
        String completedStatus;
        for (TaskStatus ts : [
            SELECT MasterLabel, IsClosed, IsDefault
            FROM TaskStatus
            WHERE IsClosed = true
            WITH USER_MODE
            ORDER BY IsDefault DESC, SortOrder ASC
        ]) {
            completedStatus = ts.MasterLabel;
            break;
        }

        List<Task> tasks = new List<Task>();
        for (Request req : requests) {
            tasks.add(new Task(
                WhatId       = req.opportunityId,
                WhoId        = req.contactId,
                Subject      = String.isBlank(req.subject) ? '商談メモ' : req.subject,
                Description  = req.notes,
                ActivityDate = (req.activityDate == null) ? Date.today() : req.activityDate,
                Status       = completedStatus
            ));
        }
        insert tasks;

        List<Result> results = new List<Result>();
        for (Task t : tasks) {
            Result r = new Result();
            r.taskId = t.Id;
            results.add(r);
        }
        return results;
    }
}

SfOpportunityNotesを使用して、添付の議事録を006fj000009riFYAAYの商談に記録してください

カスタム権限「商談メモを活動として記録」を付与したのでもう一度お願いします！