Salesforce Hosted MCP ServersにカスタムMCPサーバーを追加してみた

/**
 * 商談メモ（議事録）を、指定した商談に紐づく完了済みの活動(ToDo / Task)として記録するInvocable Action。
 * カスタムMCPサーバーのツールとして公開して利用する。
 */
global with sharing class LogOpportunityMeetingNote {

    global class Request {
        @InvocableVariable(label='商談ID' description='メモを紐付ける商談(Opportunity)のレコードID' required=true)
        global Id opportunityId;

        @InvocableVariable(label='メモ本文' description='活動として記録する議事録・商談メモの本文' required=true)
        global String notes;

        @InvocableVariable(label='件名' description='活動の件名。未指定の場合は「商談メモ」を使用')
        global String subject;

        @InvocableVariable(label='活動日' description='活動の日付。未指定の場合は本日')
        global Date activityDate;

        @InvocableVariable(label='関連連絡先ID' description='メモに紐付ける担当者(Contact)のレコードID（任意）')
        global Id contactId;
    }

    global class Result {
        @InvocableVariable(label='作成された活動ID' description='登録された活動(Task)のレコードID')
        global Id taskId;
    }

    @InvocableMethod(
        label='商談メモを活動として記録'
        description='議事録・商談メモを、指定した商談に紐づく完了済みの活動(ToDo)として記録します。'
    )
    global static List<Result> logMeetingNotes(List<Request> requests) {
        // 組織のロケール（"完了"/"Completed" 等）に依存しないよう、
        // クローズ扱いの状況(Status)を動的に取得する。
        String completedStatus;
        for (TaskStatus ts : [
            SELECT MasterLabel, IsClosed, IsDefault
            FROM TaskStatus
            WHERE IsClosed = true
            ORDER BY IsDefault DESC, SortOrder ASC
        ]) {
            completedStatus = ts.MasterLabel;
            break;
        }

        List<Task> tasks = new List<Task>();
        for (Request req : requests) {
            tasks.add(new Task(
                WhatId       = req.opportunityId,
                WhoId        = req.contactId,
                Subject      = String.isBlank(req.subject) ? '商談メモ' : req.subject,
                Description  = req.notes,
                ActivityDate = (req.activityDate == null) ? Date.today() : req.activityDate,
                Status       = completedStatus
            ));
        }
        insert tasks;

        List<Result> results = new List<Result>();
        for (Task t : tasks) {
            Result r = new Result();
            r.taskId = t.Id;
            results.add(r);
        }
        return results;
    }
}

ミーティング実施日: 2026/05/31
タイトル: Hosted MCP ServersにカスタムMCPサーバーを追加してみた件
内容: 検証用にHosted MCP ServersにカスタムMCPサーバーを追加して色々とゴニョゴニョしてみたよ

カスタムコネクタのSfOpportunityNotesを使ってSalesforceのレコードID: 006fj000009riFRAAYの商談に議事録を追加してください